开启辅助访问
切换到宽版

天天ASP家园官方Q群

天天ASP家园网友互动群

群1: 697497501(新手学习互助群)

群2: 47598123(进阶应用群)

天天ASP家园»论坛 › 技术交流 › ASP技术 › 常用加密解密算法技术经典ASP终结版（天天asp家园首发）
返回列表 发新帖
查看: 2224|回复: 2

[文章教程] 常用加密解密算法技术经典ASP终结版（天天asp家园首发）

[复制链接]
ttasp 发表于 2019-4-4 11:39:25 | 显示全部楼层 |阅读模式
1.ESCAPE加密与解密（支持中文）；

  2. <%
  3. dim str,str2,str3
  4. str = "天天asp"
  5. str2 = escape(str) '加密
  6. str3 = UnEscape(str2) '解密

  8. Response.Write("原字符："&str& "<br />")  
  9. Response.Write("加密后：" &str2&"<br />")
  10. Response.Write("解密后：" &str3&"<br />")
  11. %>
复制代码


2.BASE64编码解码（支持中文）
  1. <%
  2. Function Base64Encode(ByVal Str)
  3.         dim Xml, Stream, Node, Encode
  4.         Set Xml = Server.CreateObject("Msxml2.DOMDocument")
  5.         Set Stream = Server.CreateObject("ADODB.Stream")
  6.         Set Node = Xml.CreateElement("TmpNode")
  7.         Node.DataType = "bin.base64"
  8.         Stream.Charset = "UTF-8"
  9.         Stream.Type = 2 '0 = AdStateClosed/1 = AdStateOpen
  10.         Stream.Open()
  11.         Stream.WriteText(Str)
  12.         Stream.Position = 0
  13.         Stream.Type = 1 '1=adTypeBinary/2=adTypeText
  14.         Node.NodeTypedValue = Stream.Read(-1) '-1 = AdReadAll
  15.         Stream.Close()
  16.         Encode = Replace(Node.Text, Vblf, "")
  17.         Encode = Replace(Encode, Vbcr, "")
  18.         Base64Encode = Replace(Encode,"77u/","") 'base64编码后，比起.net多了77u/
  19.         Set Node = Nothing
  20.         Set Stream = Nothing
  21.         Set Xml = Nothing
  22. End Function

  24. Function Base64Decode(ByVal Str)
  25.         Dim Val
  26.         With Server.CreateObject("Msxml2.DOMDocument").CreateElement("TmpNode")
  27.                 .DataType = "bin.base64"
  28.                 .Text = Str
  29.                 Val = .NodeTypedValue
  30.         End With
  31.         With Server.CreateObject("ADODB.Stream")
  32.                 .Type = 1
  33.                 .Open
  34.                 .Write Val
  35.                 .Position = 0
  36.                 .Type = 2
  37.                 .Charset = "UTF-8"
  38.                 Base64Decode = .ReadText(-1)
  39.         End With
  40. End Function

  42. dim str,encode,newline
  43. newline="<br>"
  44. str= "asp学习交流论坛，天天ASP家园！"

  46. encode = base64Encode(str)
  47. response.write "加密前为:" & str & newline
  48. response.write "加密后为:" & encode & newline
  49. response.write "解密后为:" & base64Decode(encode) & newline
  50. %>
复制代码


下面部分代码采用了.NET COM Interop技术，所以要求系统必须有安装.NET Framework 1.1。【默认Window 2003下有预装.NET Framework 1.1，其他低版本OS默认不包含该组件，意味着可能部分XP用户如果在没有安装.NET Framework 1.1的情况下，可能会无法支持下面代码。如果有安装最低.NET Framework 1.1，那么下面的asp代码将能很好的运行在 Windows 98, ME, NT 4.0, 2000, XP, Server 2003, Vista, and Server 2008 以上 。。。等Windows系统下.】

3.MD5加密（支持中文和Base64,Hex)

QQ截图20190405132541.jpg

md5加密.rar (873 Bytes, 下载次数: 3, 售价: 1 个ASP币)

4.SHA1加密（支持中文和Base64,Hex)
sha1加密.rar (752 Bytes, 下载次数: 1, 售价: 1 个ASP币)

QQ截图20190405132541.jpg

5.SHA256加密（支持中文和Base64,Hex)

sha256

sha256

sha256.rar (749 Bytes, 下载次数: 5, 售价: 1 个ASP币)



  2. 经典ASP常用加密算法终结版
  3. <html>
  4. <head>
  5. <meta http-equiv="Content-Type" content="text/html; charset=utf-8">
  6. <title>经典ASP常用加密算法终结版</title>
  7. </head>
  8. <body>
  9. <%
  10. Function Hash(HashType, Target)
  11. On Error Resume Next

  13. Dim PlainText

  15. If IsArray(Target) = True Then PlainText = Target(0) Else PlainText = Target End If

  17. With CreateObject("ADODB.Stream")
  18. .Open
  19. .CharSet = "Windows-1252"
  20. .WriteText PlainText
  21. .Position = 0
  22. .CharSet = "UTF-8"
  23. PlainText = .ReadText
  24. .Close
  25. End With

  27. Set UTF8Encoding = CreateObject("System.Text.UTF8Encoding")
  28. Dim PlainTextToBytes, BytesToHashedBytes, HashedBytesToHex

  30. PlainTextToBytes = UTF8Encoding.GetBytes_4(PlainText)

  32. Select Case HashType
  33. Case "md5": Set Cryptography = CreateObject("System.Security.Cryptography.MD5CryptoServiceProvider") '< 64 (collisions found)
  34. Case "ripemd160": Set Cryptography = CreateObject("System.Security.Cryptography.RIPEMD160Managed")
  35. Case "sha1": Set Cryptography = CreateObject("System.Security.Cryptography.SHA1Managed") '< 80 (collision found)
  36. Case "sha256": Set Cryptography = CreateObject("System.Security.Cryptography.SHA256Managed")
  37. Case "sha384": Set Cryptography = CreateObject("System.Security.Cryptography.SHA384Managed")
  38. Case "sha512": Set Cryptography = CreateObject("System.Security.Cryptography.SHA512Managed")
  39. Case "md5HMAC": Set Cryptography = CreateObject("System.Security.Cryptography.HMACMD5")
  40. Case "ripemd160HMAC": Set Cryptography = CreateObject("System.Security.Cryptography.HMACRIPEMD160")
  41. Case "sha1HMAC": Set Cryptography = CreateObject("System.Security.Cryptography.HMACSHA1")
  42. Case "sha256HMAC": Set Cryptography = CreateObject("System.Security.Cryptography.HMACSHA256")
  43. Case "sha384HMAC": Set Cryptography = CreateObject("System.Security.Cryptography.HMACSHA384")
  44. Case "sha512HMAC": Set Cryptography = CreateObject("System.Security.Cryptography.HMACSHA512")
  45. End Select

  47. Cryptography.Initialize()

  49. If IsArray(Target) = True Then Cryptography.Key = UTF8Encoding.GetBytes_4(Target(1))

  51. BytesToHashedBytes = Cryptography.ComputeHash_2((PlainTextToBytes))

  53. For x = 1 To LenB(BytesToHashedBytes)
  54. HashedBytesToHex = HashedBytesToHex & Right("0" & Hex(AscB(MidB(BytesToHashedBytes, x, 1))), 2)
  55. Next

  57. If Err.Number <> 0 Then Response.Write(Err.Description) Else Hash = LCase(HashedBytesToHex)

  59. On Error GoTo 0
  60. End Function

  62. Response.Write(Hash("sha256HMAC","bbs.ttasp.com"))

  64. %>

  66. </body>
  67. </html>
复制代码


更新基本完成
ASP币如何冲？请看这里
回复

使用道具 举报

小叶白龙 发表于 2019-4-8 11:41:56 | 显示全部楼层
为啥我的base64加密的和你们的不一样呢
你们的代码
加密前为:你好
加密后为:5L2g5aW9
解密后为:你好

但我的为啥是
加密前为:你好
加密后为:JiMyMDMyMDsmIzIyOTA5Ow==
解密后为:你好

  1. <%@LANGUAGE="VBSCRIPT" CODEPAGE="65001"%>
  2. <%
  3.         session.codepage=65001
  4.         response.charset="utf-8"
  5.         server.scripttimeout=999999%>
  6. <%
  7.      'OPTION EXPLICIT
  8.      const BASE_64_MAP_INIT = "ABCDEFGHIJKLMNOPQRSTUVWXYZabcdefghijklmnopqrstuvwxyz0123456789+/"
  9.      dim nl
  10.      ' zero based arrays
  11.      dim Base64EncMap(63)
  12.      dim Base64DecMap(127)

  14.      ' must be called before using anything else
  15.      PUBLIC SUB initCodecs()
  16.           ' init vars
  17.           nl = "<P>" & chr(13) & chr(10)
  18.           ' setup base 64
  19.           dim max, idx
  20.              max = len(BASE_64_MAP_INIT)
  21.           for idx = 0 to max - 1
  22.                ' one based string
  23.                Base64EncMap(idx) = mid(BASE_64_MAP_INIT, idx + 1, 1)
  24.           next
  25.           for idx = 0 to max - 1
  26.                Base64DecMap(ASC(Base64EncMap(idx))) = idx
  27.           next
  28.      END SUB

  30.      ' encode base 64 encoded string
  31.      PUBLIC FUNCTION base64Encode(plain)
  32.           if len(plain) = 0 then
  33.                base64Encode = ""
  34.                exit function
  35.           end if

  37.           dim ret, ndx, by3, first, second, third
  38.           by3 = (len(plain) \ 3) * 3
  39.           ndx = 1
  40.           do while ndx <= by3
  41.                first  = asc(mid(plain, ndx+0, 1))
  42.                second = asc(mid(plain, ndx+1, 1))
  43.                third  = asc(mid(plain, ndx+2, 1))
  44.                ret = ret & Base64EncMap(  (first \ 4) AND 63 )
  45.                ret = ret & Base64EncMap( ((first * 16) AND 48) + ((second \ 16) AND 15 ) )
  46.                ret = ret & Base64EncMap( ((second * 4) AND 60) + ((third \ 64) AND 3 ) )
  47.                ret = ret & Base64EncMap( third AND 63)
  48.                ndx = ndx + 3
  49.           loop
  50.           ' check for stragglers
  51.           if by3 < len(plain) then
  52.                first  = asc(mid(plain, ndx+0, 1))
  53.                ret = ret & Base64EncMap(  (first \ 4) AND 63 )
  54.                if (len(plain) MOD 3 ) = 2 then
  55.                     second = asc(mid(plain, ndx+1, 1))
  56.                     ret = ret & Base64EncMap( ((first * 16) AND 48) + ((second \ 16) AND 15 ) )
  57.                     ret = ret & Base64EncMap( ((second * 4) AND 60) )
  58.                else
  59.                     ret = ret & Base64EncMap( (first * 16) AND 48)
  60.                     ret = ret & "="
  61.                end if
  62.                ret = ret & "="
  63.           end if

  65.           base64Encode = ret
  66.      END FUNCTION

  68.      ' decode base 64 encoded string
  69.      PUBLIC FUNCTION base64Decode(scrambled)

  71.           if len(scrambled) = 0 then
  72.                base64Decode = ""
  73.                exit function
  74.           end if

  76.           ' ignore padding
  77.           dim realLen
  78.           realLen = len(scrambled)
  79.           do while mid(scrambled, realLen, 1) = "="
  80.                realLen = realLen - 1
  81.           loop
  82.           dim ret, ndx, by4, first, second, third, fourth
  83.           ret = ""
  84.           by4 = (realLen \ 4) * 4
  85.           ndx = 1
  86.           do while ndx <= by4
  87.                first  = Base64DecMap(asc(mid(scrambled, ndx+0, 1)))
  88.                second = Base64DecMap(asc(mid(scrambled, ndx+1, 1)))
  89.                third  = Base64DecMap(asc(mid(scrambled, ndx+2, 1)))
  90.                fourth = Base64DecMap(asc(mid(scrambled, ndx+3, 1)))
  91.                ret = ret & chr( ((first * 4) AND 255) +   ((second \ 16) AND 3))
  92.                ret = ret & chr( ((second * 16) AND 255) + ((third \ 4) AND 15) )
  93.                ret = ret & chr( ((third * 64) AND 255) +  (fourth AND 63) )
  94.                ndx = ndx + 4
  95.           loop
  96.           ' check for stragglers, will be 2 or 3 characters
  97.           if ndx < realLen then
  98.                first  = Base64DecMap(asc(mid(scrambled, ndx+0, 1)))
  99.                second = Base64DecMap(asc(mid(scrambled, ndx+1, 1)))
  100.                ret = ret & chr( ((first * 4) AND 255) +   ((second \ 16) AND 3))
  101.                if realLen MOD 4 = 3 then
  102.                     third = Base64DecMap(asc(mid(scrambled,ndx+2,1)))
  103.                     ret = ret & chr( ((second * 16) AND 255) + ((third \ 4) AND 15) )
  104.                end if
  105.           end if

  107.           base64Decode = ret
  108.      END FUNCTION
  109. Function UrlDecode(encodestr)

  111. newstr=""
  112. havechar=false
  113. lastchar=""
  114. for i=1 to len(encodestr)
  115. char_c=mid(encodestr,i,1)
  116. if char_c="+" then
  117. newstr=newstr & " "
  118. elseif char_c="%" then
  119. next_1_c=mid(encodestr,i+1,2)
  120. next_1_num=cint("&h" & next_1_c)

  122. if havechar then
  123. havechar=false
  124. newstr=newstr & chr(cint("&h" & lastchar & next_1_c))
  125. else
  126. if abs(next_1_num)<=127 then
  127. newstr=newstr & chr(next_1_num)
  128. else
  129. havechar=true
  130. lastchar=next_1_c
  131. end if
  132. end if
  133. i=i+2
  134. else
  135. newstr=newstr & char_c
  136. end if

  138. next
  139. UrlDecode=newstr
  140. End Function



  144.    call initCodecs
  145.         inp = "你好"
  146.     inp=server.htmlEncode(inp)
  147.     encode = base64Encode(inp)
  148.     decode= base64Decode(encode)

  150.     response.write "urlE = " & inp & nl
  151.     response.write "Encoded value = " & encode & nl
  152.     response.write "Decoded value = " & UrlDecode(decode) & nl
  153.         %>
复制代码


好像和编码有关
ASP币如何冲？请看这里
回复 支持 反对

使用道具 举报

xuanxiao 发表于 2019-7-7 14:34:24 | 显示全部楼层
小叶白龙 发表于 2019-4-8 11:41
为啥我的base64加密的和你们的不一样呢
你们的代码
加密前为:你好

统一下编码，没问题的
ASP币如何冲？请看这里
回复 支持 反对

使用道具 举报

返回列表 发新帖
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册

本版积分规则

快速回复 返回顶部 返回列表

在线客服

售前咨询
售后咨询
服务热线
023-58418553
微信公众号