开启辅助访问
切换到宽版

天天ASP家园官方Q群

天天ASP家园网友互动群

群1: 697497501(新手学习互助群)

群2: 47598123(进阶应用群)

天天ASP家园»论坛 › 技术交流 › ASP技术 › ASP接收其他接口平台提交过来的表单数据
返回列表 发新帖
查看: 423|回复: 0

[文章教程] ASP接收其他接口平台提交过来的表单数据

[复制链接]
xuanxiao 发表于 2022-8-12 18:09:12 | 显示全部楼层 |阅读模式
导读：
一般情况下，ASP都是用来Request.Form来获取post/get提交过来的数据，但实际上呢，如果是java或php提交过来的话，用Request.Form得到的可能就是空值。因此，最稳妥的办法是使用二进制流得到数据。

第一种方法：根据键名获取数据
  1. <%
  2. '1.得到Request表单数据字节数
  3. FormSize = Request.TotalBytes
  4. '2.使用二进制读取Request表单数据
  5. FormData = Request.BinaryRead(FormSize)
  6. '3.创建对象数组
  7. Set dataArray = Server.CreateObject("Scripting.Dictionary")  ' Server.CreateObject("Scripting.Dictionary")
  8. dataArray.Add "pay_id", GetFormVal(FormData,"pay_id")
  9. dataArray.Add "pay_money", GetFormVal(FormData,"pay_money")
  10. dataArray.Add "pay_price", GetFormVal(FormData,"pay_price")
  11. dataArray.Add "pay_no", GetFormVal(FormData,"pay_no")
  12. dataArray.Add "pay_time", GetFormVal(FormData,"pay_time")
  13. dataArray.Add "pay_type", GetFormVal(FormData,"pay_type")
  14. dataArray.Add "param", GetFormVal(FormData,"param")
  15. dataArray.Add "sign", GetFormVal(FormData,"sign")
  16. '4.输出测试
  17. response.write(dataArray("sign"))

  19. '/**获取表单数据里的值
  20. ' * @param FormData 二进制的表单数据
  21. ' * @param FormName  键名
  22. ' */
  23. Function GetFormVal(FormData,FormName)
  24.         'Chr返回一个Unicode字符，2个字节
  25.         'ChrB返回一个ANSI字符，1个字节
  26.         charBs = ChrB(13) & ChrB(10)
  27.         Divider = LeftB(FormData, InStrB(FormData, charBs) - 1)
  28.         GetFormVal = ""
  29.         StartPos = LenB(Divider) + 2
  30.         FormName = Chr(34) & FormName & Chr(34)
  31.         Do While StartPos > 0
  32.         strlen = InStrB(StartPos, FormData, charBs) - StartPos
  33.         SearchStr = MidB(FormData, StartPos, strlen)
  34.         If InStr(binTostr(SearchStr,"utf-8"), FormName) > 0 Then
  35.                 ValStart = InStrB(StartPos, FormData, charBs & charBs) + 4
  36.                 ValLen = InStrB(StartPos, FormData, Divider) - 2 - ValStart
  37.                 ValContent = MidB(FormData, ValStart, ValLen)
  38.                 If GetFormVal <> "" Then
  39.                         GetFormVal = GetFormVal & "," & binTostr(ValContent,"utf-8")
  40.                 Else
  41.                         '二进制转化
  42.                         GetFormVal = binTostr(ValContent,"utf-8")
  43.                 End If
  44.         End If
  45.         If InStrB(StartPos, FormData, Divider) < 1 Then
  46.         Exit Do
  47.         End If
  48.         StartPos = InStrB(StartPos, FormData, Divider) + LenB(Divider) + 2
  49.         Loop
  50. End Function

  52. '/**二进制转化（将二进制转换为字符串）
  53. ' * @param vin 要转换的二进制
  54. ' * @param charset 编码方式 utf-8或者gb2312
  55. ' */
  56. Function binTostr(vin,charset)
  57.     Const adTypeText = 2
  58.     Dim BytesStream,StringReturn
  59.     Set BytesStream = Server.CreateObject("ADODB.Stream")
  60.         With BytesStream
  61.                 .Type = adTypeText
  62.                 .Open
  63.                 .WriteText vin
  64.                 .Position = 0
  65.                 .Charset = charset
  66.                 .Position = 2
  67.                 StringReturn = .ReadText
  68.                 .Close
  69.         End With
  70.         Set BytesStream = Nothing
  71.         binTostr = StringReturn
  72. End Function
  73. %>
复制代码

第二种方法：直接返回完整的键值对数组
  1. <%
  2. '1.得到Request表单数据字节数
  3. FormSize = Request.TotalBytes
  4. '2.使用二进制读取Request表单数据
  5. FormData = Request.BinaryRead(FormSize)
  6. '3.获取键值对格式的数组
  7. Set dataArray=GetFormData(FormData)
  8. '4.输出测试
  9. response.write(dataArray("sign"))

  11. '/**获取表单数据
  12. ' * @param FormData 二进制的表单数据
  13. ' * @return 返回键值对格式的数组
  14. ' */
  15. Function GetFormData(FormData)
  16.         'Chr返回一个Unicode字符，2个字节
  17.         'ChrB返回一个ANSI字符，1个字节
  18.         charBs = ChrB(13) & ChrB(10)
  19.         Divider = LeftB(FormData, InStrB(FormData, charBs) - 1)
  20.         StartPos = LenB(Divider) + 2
  21.         '创建对象数组
  22.         Set dataArray = Server.CreateObject("Scripting.Dictionary")  ' Server.CreateObject("Scripting.Dictionary")
  23.         Do While StartPos > 0
  24.                 strlen = InStrB(StartPos, FormData, charBs) - StartPos
  25.                 SearchStr = MidB(FormData, StartPos, strlen)
  26.                 '1.获取单个表单元素属性，如：Content-Disposition: form-data; name="键名"
  27.                 FormItem=binTostr(SearchStr,"utf-8")
  28.                 '2.获取键名
  29.                 FormName=Right(FormItem,Len(FormItem)-Instr(FormItem,"="))
  30.                 '3.去掉键名的双引号
  31.                 FormName = Replace(FormName, """", "")
  32.                 FormValue=""
  33.                 If FormName <> "" Then
  34.                         ValStart = InStrB(StartPos, FormData, charBs & charBs) + 4
  35.                         ValLen = InStrB(StartPos, FormData, Divider) - 2 - ValStart
  36.                         ValContent = MidB(FormData, ValStart, ValLen)
  37.                         If FormValue <> "" Then
  38.                                 FormValue = FormValue & "," & binTostr(ValContent,"utf-8")                       
  39.                         Else
  40.                                 '二进制转化
  41.                                 FormValue = binTostr(ValContent,"utf-8")
  42.                         End If
  43.                         '添加元素到数组中
  44.                         dataArray.Add FormName, FormValue
  45.                 End If               
  46.                 If InStrB(StartPos, FormData, Divider) < 1 Then
  47.                         Exit Do
  48.                 End If
  49.                 StartPos = InStrB(StartPos, FormData, Divider) + LenB(Divider) + 2
  50.         Loop
  51.         Set GetFormData=dataArray
  52.         Set dataArray=nothing
  53. End Function

  55. '/**二进制转化（将二进制转换为字符串）
  56. ' * @param vin 要转换的二进制
  57. ' * @param charset 编码方式 utf-8或者gb2312
  58. ' */
  59. Function binTostr(vin,charset)
  60.     Const adTypeText = 2
  61.     Dim BytesStream,StringReturn
  62.     Set BytesStream = Server.CreateObject("ADODB.Stream")
  63.         With BytesStream
  64.                 .Type = adTypeText
  65.                 .Open
  66.                 .WriteText vin
  67.                 .Position = 0
  68.                 .Charset = charset
  69.                 .Position = 2
  70.                 StringReturn = .ReadText
  71.                 .Close
  72.         End With
  73.         Set BytesStream = Nothing
  74.         binTostr = StringReturn
  75. End Function
  76. %>
复制代码
ASP币如何冲？请看这里
回复

使用道具 举报

返回列表 发新帖
高级模式
B Color Image Link Quote Code Smilies
您需要登录后才可以回帖 登录 | 注册

本版积分规则

快速回复 返回顶部 返回列表

在线客服

售前咨询
售后咨询
服务热线
023-58418553
微信公众号